dnl  AUTOCONF configuration for TRAMPOLINE
dnl  Bruno Haible 2001-01-27
dnl
AC_INIT(trampoline_r.h.in)
AC_CONFIG_HEADER(config.h)
AC_PROG_CC
AC_PROG_CPP
AC_PROG_GCC_TRADITIONAL
CL_CC_GCC
CL_AS_UNDERSCORE
CL_PROG_RANLIB
AC_PROG_MAKE_SET
CL_PROG_INSTALL
CL_PROG_CP
CL_PROG_LN
CL_PROG_LN_S
CL_CANONICAL_HOST(../../autoconf)
CL_CANONICAL_HOST_CPU_FOR_FFCALL
PACKAGE=callback
AM_DISABLE_SHARED
AM_PROG_LIBTOOL
CL_VOID
CL_STDC_HEADERS
AC_CHECK_HEADERS(unistd_h)
CL_GETPAGESIZE
CL_MACH_VM
CL_OPENFLAGS
CL_MMAP
CL_MPROTECT
CL_SHM_H
CL_SHM
dnl See above. Avoid duplicate warning.
dnl CL_CANONICAL_HOST(../../autoconf)
dnl CL_CANONICAL_HOST_CPU_FOR_FFCALL
CL_CODEEXEC
CPU_OBJECTS=''
if test ${host_cpu} = hppa -o ${host_cpu} = ia64; then
  CPU_OBJECTS="$CPU_OBJECTS "'tramp-$(CPU).lo'
fi
if test ${host_cpu} = rs6000; then
  case "${host_os}" in
    aix*) CPU_OBJECTS="$CPU_OBJECTS "'tramp-$(CPU).lo' ;;
    *) ;;
  esac
fi
if test ${host_cpu} = sparc -o ${host_cpu} = sparc64 -o ${host_cpu} = alpha -o ${host_cpu} = hppa -o ${host_cpu} = convex; then
  CPU_OBJECTS="$CPU_OBJECTS "'cache-$(CPU).lo'
fi
if test ${host_cpu} = rs6000; then
  case "${host_os}" in
    aix*) ;;
    *) CPU_OBJECTS="$CPU_OBJECTS "'cache-$(CPU).lo' ;;
  esac
fi
AC_SUBST(CPU_OBJECTS)
if test ${host_cpu} = mips -o ${host_cpu} = mipsn32 -o ${host_cpu} = mips64; then
AC_CHECK_HEADERS(sys/cachectl.h)
fi
if test ${host_cpu} = m88k; then
AC_CHECK_HEADERS(sys/m88kbcs.h)
fi
AC_OUTPUT(Makefile)
